пятница, 14 августа 2015 г.

Mikrotik - Скрипт для автоматического создания бэкапов и отправки на почту Gmail

Представленные ниже скрипт можно просто добавить в "Шедулер" и назначить время его работы. Незабываем изменить имя пользователя и пароль в скрипте. Скрипт универсален. Если у вас несколько "активок" от Mikrotik, то он подойдет к любой, с версией ОС выше 6.1

Не забудьте, что Gmail по умолчанию блокирует прием писем из неизвестного источника, кем для него является Mikrotik. Изменить это можно в настройках безопасности Gmail. Так же обратите внимание, что Аккаунт и пароль находятся в отрытом виде, любой кто имеет хотя бы доступ оператора к устройству, где вы пропишите данный скрипт, сможет увидеть логин и пароль. С следствии чего, лучше создать отдельную учетную запись для сбора бэкапов с устройств на Gmail.

Скрипт:

{
:log info "Starting Backup Script...";
:local sysname [/system identity get name];
:local sysver [/system package get system version];
:log info "Flushing DNS cache...";

/ip dns cache flush;
:delay 2;
:log info "Deleting last Backups...";
:foreach i in=[/file find] do={:if ([:typeof [:find [/file get $i name] \
"$sysname-backup-"]]!="nil") do={/file remove $i}};
:delay 2;
:local smtpserv [:resolve "smtp.gmail.com"];
:local Eaccount "ваш_акаунт@gmail.com";
:local pass "ваш_пароль";
:local backupfile ("$sysname-backup-" . \
[:pick [/system clock get date] 7 11] . [:pick [/system \
clock get date] 0 3] . [:pick [/system clock get date] 4 6] . ".backup");
:log info "Creating new Full Backup file...";
/system backup save name=$backupfile;
:delay 2;
:log info "Sending Full Backup file via E-mail...";
/tool e-mail send from="<$Eaccount>" to=$Eaccount server=$smtpserv \
port=587 user=$Eaccount password=$pass start-tls=yes file=$backupfile \
subject=("$sysname Full Backup (" . [/system clock get date] . ")") \
body=("$sysname full Backup file see in attachment.\nRouterOS version: \
$sysver\nTime and Date stamp: " . [/system clock get time] . " " . \
[/system clock get date]);
:delay 5;
:local exportfile ("$sysname-backup-" . \
[:pick [/system clock get date] 7 11] . [:pick [/system \
clock get date] 0 3] . [:pick [/system clock get date] 4 6] . ".rsc");
:log info "Creating new Setup Script file...";
/export verbose file=$exportfile;
:delay 2;
:log info "Sending Setup Script file via E-mail...";
/tool e-mail send from="<$Eaccount>" to=$Eaccount server=$smtpserv \
port=587 user=$Eaccount password=$pass start-tls=yes file=$exportfile \
subject=("$sysname Setup Script Backup (" . [/system clock get date] . \
")") body=("$sysname Setup Script file see in attachment.\nRouterOS \
version: $sysver\nTime and Date stamp: " . [/system clock get time] . " \
" . [/system clock get date]);
:delay 5;
:log info "All System Backups emailed successfully.\nBackuping completed.";
}





1 комментарий: